uas-platform/build.gradle

plugins {
    id "io.spring.dependency-management" version "1.0.7.RELEASE" apply false
    id "org.springframework.boot" version "2.1.4.RELEASE" apply false
}

allprojects {
    group 'com.usoftchina.uas'
    version '2.0.0-SNAPSHOT'
}

subprojects { Project subproject ->
    if (subproject.name in ["framework", "applications", "runtime", "scm", "cloud", "plm", "cost", "assert", "fa", "sys", "cust", "pm", "ec"]) {
        return
    }
    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'maven'
    apply plugin: 'io.spring.dependency-management'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    [compileJava,compileTestJava,javadoc]*.options*.encoding = 'UTF-8'

    ext {
        springBootVersion = '2.1.4.RELEASE'
        springCloudVersion = 'Greenwich.SR1'
        // dependencies
        alibabaThreadLocal = 'com.alibaba:transmittable-thread-local:2.10.2'
        mysqlConnector = 'mysql:mysql-connector-java:6.0.6'
        ojdbc = 'com.oracle:ojdbc6:11.2.0'
        mybatisSpringBoot = 'org.mybatis.spring.boot:mybatis-spring-boot-starter:2.0.1'
        pageHelperSpringBoot = 'com.github.pagehelper:pagehelper-spring-boot-starter:1.2.7'
        gson = 'com.google.code.gson:gson:2.8.5'
        guava = 'com.google.guava:guava:28.0-jre'
    }

    repositories {
        mavenLocal()
        mavenCentral()
        maven { url "http://repo.spring.io/libs-milestone" }
        maven { url "http://maven.aliyun.com/nexus/content/groups/public/" }
        maven { url "https://oss.sonatype.org/content/repositories/snapshots"}
    }

    dependencyManagement {
        imports {
            mavenBom "org.springframework.boot:spring-boot-dependencies:${springBootVersion}"
        }
    }

    uploadArchives {
        repositories {
            mavenDeployer {
                repository(url: "http://maven.ubtob.com/artifactory/libs-snapshot-local") {
                    authentication(userName: "yingp", password: "111111")
                }
            }
        }
    }.dependsOn build

    sourceSets {
        main {
            resources {
                srcDirs = ["src/main/java", "src/main/resources"]
            }
        }
    }
}