uu-platform/build.gradle

plugins {
    id "io.spring.dependency-management" version "1.0.7.RELEASE" apply false
    id "org.springframework.boot" version "2.1.4.RELEASE" apply false
    id "com.google.protobuf" version "0.8.8" apply false
    id "com.palantir.docker" version "0.22.1" apply false
}

allprojects {
    group 'com.usoftchina.uu'
    version '1.0.0-SNAPSHOT'
}

subprojects { Project subproject ->
    if (subproject.name in ["apis", "services", "external", "shared", "runtime"]) {
        return
    }
    apply plugin: 'java'
    apply plugin: 'idea'
    apply plugin: 'maven'
    apply plugin: 'io.spring.dependency-management'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    [compileJava,compileTestJava,javadoc]*.options*.encoding = 'UTF-8'

    ext {
        dockerGroup = 'uu'
        dockerRegistry = '10.1.81.1:4000'
        springBootVersion = '2.1.4.RELEASE'
        springCloudVersion = 'Greenwich.SR1'
        grpcVersion = '1.20.0'
        protocVersion = '3.7.1'
        feignFormVersion = '3.8.0'
        // dependencies
        grpcSpringBoot = 'io.github.lognet:grpc-spring-boot-starter:3.2.2'
        alibabaThreadLocal = 'com.alibaba:transmittable-thread-local:2.10.2'
        mysqlConnector = 'mysql:mysql-connector-java:6.0.6'
        mybatisSpringBoot = 'org.mybatis.spring.boot:mybatis-spring-boot-starter:2.0.1'
        pageHelperSpringBoot = 'com.github.pagehelper:pagehelper-spring-boot-starter:1.2.7'
        gson = 'com.google.code.gson:gson:2.8.5'
    }

    repositories {
        mavenLocal()
        mavenCentral()
        maven { url "http://repo.spring.io/libs-milestone" }
        maven { url "http://maven.aliyun.com/nexus/content/groups/public/" }
        maven { url "https://oss.sonatype.org/content/repositories/snapshots"}
    }

    dependencyManagement {
        imports {
            mavenBom "org.springframework.boot:spring-boot-dependencies:${springBootVersion}"
            mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
        }
    }

    uploadArchives {
        repositories {
            mavenDeployer {
                repository(url: "http://maven.ubtob.com/artifactory/libs-snapshot-local") {
                    authentication(userName: "yingp", password: "111111")
                }
            }
        }
    }.dependsOn build
}